![](https://help.apple.com/assets/6467B9B3CF36103D3A318861/6467B9B8CF36103D3A318879/zh_CN/784be3dfed809d4b6bb7cc427d8c5f01.png)
COUNTIF
COUNTIF 函数返回某个集合内满足给定条件的单元格的个数。
COUNTIF(待检验阵列, 条件)
注释
每个待检验阵列值都要与条件进行比较。如果某值满足条件测试,则它将包括在计数中。
示例 |
---|
以下表格中的信息没什么意义,但能说明包括在结果中的 COUNTIF 参数的参数类型。 假设表格如下: |
A | B | C | D | |
---|---|---|---|---|
1 | 100 | 200 | 300 | 400 |
2 | lorem | ipsum | dolor | sit |
3 | 100 | 200 | 300 | sit |
4 | TRUE | TRUE | FALSE | FALSE |
5 | 200 | 400 |
=COUNTIF(A1:D1, ">0") 返回 4,因为此集合内所有单元格中的值都大于 0。 =COUNTIF(A1:D1, "<>100") 返回 3,因为此集合内三个单元格中的值都不是 100。你也可以使用 ≠ 运算符 =COUNTIF(A3:D3, ">=100") 返回 3,因为比较时三个数字全都大于或等于 100,且文本值被忽略。你也可以使用 ≥ 运算符。 =COUNTIF(A1:D5, "=ipsum") 返回 1,因为文本字符串“ipsum”在该范围引用的集合内出现一次。 =COUNTIF(A1:D5, "=*t") 返回 2,因为以字母“t”结尾的字符串在该范围引用的集合内出现两次。 |
使用 REGEX 示例 |
---|
假设表格如下: |
A | B | |
---|---|---|
1 | 45 | marina@example.com |
2 | 41 | Aaron |
3 | 29 | michael@example.com |
4 | 64 | katrina@example.com |
5 | 12 | Sarah |
=COUNTIF(B1:B5, REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})")) 返回 B1:B5 中包含电子邮件地址的单元格的数字。 |
示例—调查结果 |
---|
本示例汇总了统计函数中使用的举例说明。它基于假设的调查。这项调查很短(只有 5 个问题)且接受调查者非常有限 (10)。应该以等级 1 到 5 回答每个问题(可能范围从“从不”到“总是”),也可以不回答问题。每个调查都先编号 (ID#) 再邮寄。下表显示了结果。回答超出范围(错误)或未回答的问题在表格中使用空白单元格表示。 |
A | B | C | D | E | F | |
---|---|---|---|---|---|---|
1 | ID# | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | 5 | 4 | 4 | 3 | 4 |
3 | 105 | 3 | 2 | 2 | 3 | 3 |
4 | 102 | 4 | 4 | 4 | 4 | |
5 | 104 | 3 | 4 | 2 | 4 | 3 |
6 | 107 | 4 | 3 | 3 | ||
7 | 106 | 4 | 3 | 3 | 4 | |
8 | 109 | 3 | 4 | 1 | 3 | 4 |
9 | 111 | 5 | 2 | 2 | 5 | 3 |
10 | 121 | 4 | 2 | 3 | 3 | 4 |
11 | 115 | 3 | 3 | 3 | 3 |
为了举例说明部分函数,假定字母前缀中包括调查编号,且数值范围是 A–E,而非 1–5。那么表格将如下: |
A | B | C | D | E | F | |
---|---|---|---|---|---|---|
1 | ID# | Q1 | Q2 | Q3 | Q4 | Q5 |
2 | 101 | E | D | D | C | D |
3 | 105 | C | B | B | C | C |
4 | 102 | D | D | D | D | |
5 | 104 | C | D | B | D | C |
6 | 107 | D | C | C | ||
7 | 106 | D | C | C | D | |
8 | 109 | C | D | A | C | D |
9 | 111 | E | B | B | E | C |
10 | 121 | D | B | C | D | |
11 | 115 | C | C | C | C | C |
使用此表格中的数据和部分可用统计函数,可以收集有关调查结果的信息。请记住,本示例故意设为小型,以便可让结果比较明显。但是,如果具有 50、100 或更多接受调查者,且可能具有很多问题,则结果将不明显。 |
函数和参数 | 结果描述 |
---|---|
=CORREL(B2:B11, C2:C11) | 使用线性回归分析确定问题 1 和问题 2 之间的相关性。相关性可衡量两个变量(此示例中是指调查问题的答案)一起变化的程度。这具体取决于问题:如果被调查者对问题 1 的回答值比问题 1 的平均值高(或低),则被调查者对问题 2 的回答值是否也比问题 2 的平均值高(或低)?在此示例中,回答不明显相关 (-0.1732)。 |
=COUNT(A2:A11) 或 =COUNTA(A2:A11) | 确定返回的调查总数 (10)。请注意,如果调查编号不是数值,则需要使用 COUNTA,而非 COUNT。 |
=COUNT(B2:B11) 或 =COUNTA(B2:B11) | 确定第一个问题 (9) 的答案总数。通过跨行扩展此公式,可以确定每个问题的答案总数。由于所有数据都是数值,因此 COUNTA 返回的结果相同。但是,如果调查使用 A-E,而非 1-5,将需要使用 COUNTA 来记录结果。 |
=COUNTBLANK(B2:B11) | 确定空单元格(表示无效回答或无回答)的数量。如果跨行扩展此公式,则将发现问题 3(D 列)具有 3 个无效或未回答的答案。这可能会让你在调查中查看此问题,了解措辞是否有争议或较差,因为其他问题的错误或未回答答案都没有超过 1 个。 |
=COUNTIF(B2:B11, "=5") | 确定对特定问题(此示例中是问题 1)给出等级 5 的被调查者人数。如果跨行扩展此公式,将了解到仅问题 1 和 4 是任何被调查者均给出了问题答案 5。如果调查使用 A-E 范围,将使用 =COUNTIF(B2:B11, "=E")。 |
=COUNTIF(B2:B11, "<>5") | 确定对特定问题(此示例中是问题 1)没有给出 5 分的被调查者人数。 |
=COVAR(B2:B11, C2:C11) | 确定问题 1 和问题 2 的协方差。协方差可衡量两个变量(此示例中是指调查问题的答案)一起变化的程度。这具体取决于问题:如果被调查者对问题 1 的回答值比问题 1 的平均值高(或低),则被调查者对问题 2 的回答值是否也比问题 2 的平均值高(或低)? 注:COVAR 不会使用数值范围 A–E 处理表格,因为它需要数值参数。 |
=STDEV(B2:B11) 或 =STDEVP(B2:B11) | 确定问题 1 回答的标准偏差(离差的一种度量)。如果跨行扩展此公式,将发现问题 3 的回答具有最高标准偏差。如果结果表示被调查者总体的回答,而不是某个人的回答,则使用 STDEVP,而不是 STDEV。请注意,STDEV 是 VAR 的平方根。 |
=VAR(B2:B11) 或 =VARP(B2:B11) | 确定问题 1 回答的方差(离差的一种度量)。如果跨行扩展此公式,将发现问题 5 的回答具有最低方差。如果结果表示被调查者总体的回答,而不是某个人的回答,则使用 VARP,而不是 VAR。请注意,VAR 是 STDEV 的平方。 |